Tasta Caps Lock ocupă terenul principal de la tastatură și nu își trage greutatea. Acest script ușor AutoHotkey va transforma Caps Lock într-o tastă modificatoare, astfel încât să o puteți utiliza pentru comenzi rapide personalizabile.
Cuprins
Cele elementare
Acest script vă va permite să apăsați Caps Lock+G pentru a text rapid Google de oriunde în Windows sau apăsați Caps Lock+D pentru a căuta definiția din dicționar a unui cuvânt. Aceste comenzi rapide sunt personalizabile, desigur.
Cel mai bun dintre toate, acest script inteligent vă permite în continuare să utilizați Caps Lock în mod normal. Puteți activa și dezactiva Caps Lock apăsând-o rapid de două ori. Dacă nu, Caps Lock va funcționa ca o tastă modificatoare pentru comenzile rapide.
AutoHotkey 101
AutoHotkey este o aplicație gratuită pentru Windows care se află în fundal și rulează scripturi. Puteți scrie singuri aceste scripturi sau le puteți descărca. Scripturile așteaptă, în general, apăsarea unei taste și efectuează o acțiune. În acest fel, AutoHotkey este o modalitate rapidă de a remapa taste în Windows sau de a atribui diferite acțiuni tastelor.
De exemplu, am arătat cum puteți utiliza AutoHotkey pentru a dezactiva tasta Windows, împiedicând-o să deschidă meniul Start și scoțându-vă din jocurile pentru computer pe ecran complet. Nu este nevoie să scoateți tastatura de pe tastatură.
Instalați AutoHotkey și obțineți scriptul
Descărcați AutoHotkey și instalează-l pentru a începe. Apoi, descărcați scriptul CapsLock Modifier.
Extrageți fișierul script AHK din fișierul de arhivă ZIP și plasați-l în orice folder de pe computer. Pentru a-l rula cu AutoHotkey, faceți clic dreapta pe script și selectați „Run Script”.
Scriptul rulează acum în fundal. Pentru a activa și dezactiva Caps Lock, atingeți rapid de două ori tasta Caps Lock.
Dacă nu atingeți de două ori, Caps Lock funcționează doar ca o tastă modificatoare. Cu funcțiile încorporate în script, puteți utiliza următoarele comenzi rapide oriunde în Windows:
Apăsați Caps Lock + d pentru a găsi definiția din dicționar a unui cuvânt selectat.
Apăsați Caps Lock + g pentru a căuta pe Google textul selectat oriunde în Windows.
Apăsați Caps Lock + t pentru a găsi cuvântul selectat într-un tezaur.
Apăsați Caps Lock + w pentru a căuta textul selectat pe Wikipedia.
Vrei mai multe comenzi rapide? Îți poți crea propriul cu puține cunoștințe despre scripturile AutoHotkey.
Pentru a controla AutoHotkey, căutați pictograma AutoHotkey în zona de notificare – are un fundal verde cu un H alb pe el. Pentru a opri rularea scriptului, faceți clic dreapta pe pictograma AutoHotkey și selectați „Ieșire”.
Cum functioneazã?
Dacă doriți să vedeți ce face scriptul, faceți clic dreapta pe el și selectați „Editați scriptul”. Acest lucru va deschide scriptul în Notepad și îi puteți examina codul. Scenariul este destul de scurt și ușor de înțeles. Vă recomandăm să nu descărcați și să rulați scripturi ciudate fără să le priviți și să le înțelegeți mai întâi.
Acest scenariu ne-a fost trimis de Dave Kellog. Iată partea magică a scriptului care face ca Caps Lock să funcționeze ca o tastă modificatoare dacă este apăsată de două ori:
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
Acest bit așteaptă să vadă dacă Caps Lock este apăsat de două ori și activează sau dezactivează Caps Lock. În caz contrar, scriptul captează Caps Lock și îl folosește pentru comenzile rapide modificatoare.
Restul scriptului conține acțiunile de comandă rapidă și o funcție utilă de clipboard care salvează conținutul clipboard-ului și le restabilește. Această parte este destul de necesară, deoarece funcțiile modificatoare folosesc clipboard-ul pentru a efectua acțiuni asupra textului selectat.
Doriți să vedeți scriptul complet fără a-l descărca? Iată-l:
#NoEnv ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir% ; Ensures a consistent starting directory.
;================================================================================================
; CapsLock processing. Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return
;================================================================================================
; Hot keys with CapsLock modifier. See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.
CapsLock & d::
ClipboardGet()
Run, http://www.google.com/search?q=define+%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; GOOGLE the selected text.
CapsLock & g::
ClipboardGet()
Run, http://www.google.com/search?q=%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do THESAURUS of selected word
CapsLock & t::
ClipboardGet()
Run http://www.thesaurus.com/browse/%Clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
; Do WIKIPEDIA of selected word
CapsLock & w::
ClipboardGet()
Run, https://en.wikipedia.org/wiki/%clipboard% ; Launch with contents of clipboard
ClipboardRestore()
Return
;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++
;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
OldClipboard:= ClipboardAll ;Save existing clipboard.
Clipboard:= ""
Send, ^c ;Copy selected test to clipboard
ClipWait 0
If ErrorLevel
{
MsgBox, No Text Selected!
Return
}
}
ClipboardRestore()
{
Clipboard:= OldClipboard
}
Am mai văzut scripturi AutoHotkey care transformă Caps Lock într-o tastă modificatoare, dar niciodată una care păstrează Caps Lock ca comutare dacă o apăsați de două ori. Este foarte inteligent. Mulțumim din nou lui Dave Kellog pentru că ni l-a trimis.