Cum să configurați alertele de conectivitate la internet pe Windows 10

Dacă internetul dvs. funcționează și trebuie să urmăriți când aveți sau nu o conexiune, cel mai simplu mod de a face acest lucru este să urmăriți simbolul WiFi din bara de sistem pe Windows 10. Când pierdeți conexiunea la internet, pe simbolul WiFi apare un semn de exclamare galben. De asemenea, puteți trimite ping la un site web. Dacă nu poți fi cu ochii pe bara de sistem și ping-ul pare obositor pentru tine, poți configura alerte audio de conectivitate la internet pe Windows 10 cu un script simplu.

ALERTA SPOILER: Derulați în jos și urmăriți tutorialul video de la sfârșitul acestui articol.

Alerte de conectare la internet

Acest script a fost scris inițial de Superuser Fabby și îmbunătățit de VMMF. Scriptul necesită să descărcați un utilitar gratuit numit Utilitare GNU pentru Win32. Extrageți-l și căutați în următorul folder un EXE numit Sleep.exe.

UnxUtilsusrlocalwbin

Acesta va fi folosit pentru a adăuga un timp de așteptare între verificări. Acest EXE ar trebui să fie în același folder în care salvați scriptul. Nu aveți nevoie de nimic altceva, așa că nu ezitați să-l ștergeți.

Deschideți Notepad și inserați următoarele în el. Salvați-l cu o extensie CMD și rulați fișierul. Fișierul sound.vbs să fie creat de script, așa că nu vă faceți griji.

@ECHO OFF

:whileNoInternet

set "host=8.8.8.8"

::check if internet is working

PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% neq 0 (

::the internet is not working keep cheking until it does
 echo No internet yet %TIME%
 GOTO whileNoInternet
)

echo we gained internet
::the internet is working play internet ON song

@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
 echo Sound.URL = "%file%"
 echo Sound.Controls.play
 echo do while Sound.currentmedia.duration = 0
 echo wscript.sleep 100
 echo loop
 echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet

sleep.exe 5s

::check if internet is still working

PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% == 0 (

::the internet is still working keep cheking until it does not
 echo We have internet %TIME%
 GOTO whileInternet
)

:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s

PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"

if %errorlevel% == 0 (

::the internet is still working keep cheking until it does not
 echo We have internet %TIME%
 GOTO whileInternet
)

:: if it failed twice in a row most likely internet is down

echo we lost internet
::the internet is not working anymore, play internet OFF song

@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
 echo Sound.URL = "%file%"
 echo Sound.Controls.play
 echo do while Sound.currentmedia.duration = 0
 echo wscript.sleep 100
 echo loop
 echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs

::start monitoring if it comes back
GOTO whileNoInternet

Asta e tot ce trebuie să faci. O fereastră de linie de comandă va rămâne deschisă, verificând starea conexiunii la internet. Dacă se schimbă, veți auzi sunetul Off.